punchd/punchd.nim

import asyncdispatch, asyncnet, os, strformat, strutils
from nativesockets import Domain, SockType, Protocol
from net import IpAddress, Port, `$`
import asyncutils
import message
import tcp_syni_connect
import tcp_syni_accept
import tcp_nutss_initiator
import tcp_nutss_responder

from strutils import format, join
from nativesockets import setSockOptInt

type
  Punchd = ref object
    unixSocket: AsyncSocket
    tcpSyniCP: TcpSyniConnectPuncher
    tcpSyniAP: TcpSyniAcceptPuncher
    tcpNutssInitiator: TcpNutssInitiator
    tcpNutssResponder: TcpNutssResponder

  Sigint = object of CatchableError

  # Requests
  TcpSyniConnect = object
    srcIp: IpAddress
    srcPorts: seq[Port]
    dstIp: IpAddress
    dstPorts: seq[Port]

  TcpSyniAccept = object
    dstIp: IpAddress
    dstPorts: seq[Port]
    srcIp: IpAddress
    srcPorts: seq[Port]
    seqNums: seq[uint32]

  TcpNutssInitiate = object
    srcIp: IpAddress
    srcPorts: seq[Port]
    dstIp: IpAddress
    dstPorts: seq[Port]

  TcpNutssRespond = object
    dstIp: IpAddress
    dstPorts: seq[Port]
    srcIp: IpAddress
    srcPorts: seq[Port]

const PunchdSocket = "/tmp/punchd.socket"

proc handleSigint() {.noconv.} =
  raise newException(Sigint, "received SIGINT")

proc sendToClient(unixSock: AsyncSocket, msg: string,
                  cmsgs: seq[ControlMessage] = @[]) {.async.} =
  if not unixSock.isClosed():
    let unixFd = unixSock.getFd.AsyncFD
    await unixFd.asyncSendMsg(msg, cmsgs)

proc handleRequest(punchd: Punchd, line: string,
                   unixSock: AsyncSocket) {.async.} =
  var id: string
  var sock: AsyncSocket
  try:
    let args = line.parseArgs(3)
    id = args[1]
    
    case args[0]:
    of "tcp-syni-connect":
      let req = parseMessage[TcpSyniConnect](args[2])
      proc progress(seqNumbers: seq[uint32]) {.async.} =
        echo "progress! seqNumbers: ", seqNumbers
        let content = @["tcp-syni-accept", $req.srcIp, req.srcPorts.join(","),
                        $req.dstIp, req.dstPorts.join(","),
                        seqNumbers.join(",")].join("|")
        await sendToClient(unixSock, &"progress|{id}|{content}\n")
      sock = await punchd.tcpSyniCP.connect(req.srcPorts[0], req.dstIp,
                                            req.dstPorts, progress)

    of "tcp-syni-accept":
      let req = parseMessage[TcpSyniAccept](args[2])
      sock = await punchd.tcpSyniAP.accept(req.srcPorts[0], req.dstIp,
                                           req.dstPorts, req.seqNums)

    of "tcp-nutss-initiate":
      let req = parseMessage[TcpNutssInitiate](args[2])
      proc progress() {.async.} =
        echo "progress!"
        let content = @["tcp-nutss-respond", $req.srcIp, req.srcPorts.join(","),
                        $req.dstIp, req.dstPorts.join(",")].join("|")
        await sendToClient(unixSock, &"progress|{id}|{content}\n")
      sock = await punchd.tcpNutssInitiator.initiate(req.srcPorts[0], req.dstIp,
                                                     req.dstPorts, progress)

    of "tcp-nutss-respond":
      let req = parseMessage[TcpNutssRespond](args[2])
      sock = await punchd.tcpNutssResponder.respond(req.srcPorts[0], req.dstIp,
                                                    req.dstPorts)
    
    else:
      raise newException(ValueError, "invalid request")

    await sendToClient(unixSock, &"ok|{id}\n", @[fromFd(sock.getFd.AsyncFD)])
    sock.close()

  except PunchHoleError as e:
    await sendToClient(unixSock, &"error|{id}|{e.msg}\n")
  except ValueError:
    unixSock.close

proc handleRequests(punchd: Punchd, userSock: AsyncSocket) {.async.} =
  while true:
    if userSock.isClosed:
      break
    let line = await userSock.recvLine(maxLength = 400)
    if line.len == 0:
      userSock.close()
      break
    asyncCheck punchd.handleRequest(line, userSock)

proc handleUsers(punchd: Punchd) {.async.} =
  while true:
    let user = await punchd.unixSocket.accept()
    asyncCheck punchd.handleRequests(user)

proc main() =
  setControlCHook(handleSigint)
  removeFile(PunchdSocket)
  let unixSocket = newAsyncSocket(AF_UNIX, SOCK_STREAM, IPPROTO_IP)
  unixSocket.bindUnix(PunchdSocket)
  unixSocket.listen()
  setFilePermissions(PunchdSocket,
                     {fpUserRead, fpUserWrite, fpGroupRead, fpGroupWrite,
                      fpOthersRead, fpOthersWrite})
  let punchd = Punchd(unixSocket: unixSocket,
                      tcpSyniCP: initTcpSyniConnectPuncher(),
                      tcpSyniAP: initTcpSyniAcceptPuncher(),
                      tcpNutssInitiator: initTcpNutssInitiator(),
                      tcpNutssResponder: initTcpNutssResponder())
  asyncCheck handleUsers(punchd)
  try:
    runForever()

  except Sigint:
    waitFor punchd.tcpSyniCP.cleanup()
    waitFor punchd.tcpSyniAP.cleanup()
    waitFor punchd.tcpNutssInitiator.cleanup()
    waitFor punchd.tcpNutssResponder.cleanup()
    punchd.unixSocket.close()
    removeFile(PunchdSocket)

when isMainModule:
  main()