{ stdenv, nim }:

{ name, src, nimDeps ? [], nativeBuildInputs ? [], buildInputs ? [],
  patches ? [], patchPhase ? "", ... }:

with stdenv.lib;

let
  getRecursiveInputs = getInputsFn: deps:
    optionals (deps != []) ((getInputsFn (head deps)) ++
                            (getRecursiveInputs getInputsFn (head deps).nimDeps) ++
                            (getRecursiveInputs getInputsFn (tail deps)));
  rNativeBuildInputs =
    nativeBuildInputs ++ (getRecursiveInputs (i: i.nativeBuildInputs) nimDeps);
  rBuildInputs =
    buildInputs ++ (getRecursiveInputs (i: i.buildInputs) nimDeps);
in
stdenv.mkDerivation {
  name = name;
  src = src;
  patches = patches;
  nativeBuildInputs = [ nim ] ++ (filter (i: i != nim) rNativeBuildInputs);
  buildInputs = rBuildInputs;
  nimDeps = nimDeps;
  patchPhase = patchPhase;
  LD_LIBRARY_PATH = makeLibraryPath (rBuildInputs ++ rNativeBuildInputs);
  buildPhase = ''
    HOME=$TMPDIR
    mkdir -p $HOME/.nimble/pkgs
    echo "[]" > $HOME/.nimble/packages_official.json
    '' + toString (map (dep: ''
      if [ -d ${dep}/.nimble ]; then
        cp -R ${dep}/.nimble/pkgs $HOME/.nimble/
      else
        cp -R ${dep} $HOME/.nimble/pkgs/${dep.name}
      fi
      # nimble >= 0.20.0 wants to store a nimblemeta.json here
      chmod u+w $HOME/.nimble/pkgs/${dep.name}
    ''
    ) nimDeps) + ''
    nimble install
  '';
  installPhase = ''
    mkdir $out
    nimbleDir=$TMPDIR/.nimble
    if [ -d $nimbleDir/bin ]; then
      cp -RL $nimbleDir/bin $out
    fi
    numberNimFiles=$(find $nimbleDir/pkgs/${name} -type f -name "*.nim" | wc -l)
    numberDirectories=$(find $nimbleDir/pkgs/${name} -mindepth 1 -type d | wc -l)
    if [ $numberNimFiles -gt 0 ] || [ $numberDirectories -gt 0 ]; then
      mkdir -p $out/.nimble
      cp -R $nimbleDir/pkgs $out/.nimble
    fi
  '';
}