diff --git a/default.nix b/default.nix
index 3cf5fdb..b52b4a8 100644
--- a/default.nix
+++ b/default.nix
@@ -5,6 +5,8 @@ self: super:
 
   #gnutls-latest-debug = super.enableDebugging self.gnutls-latest;
 
+  helix = super.callPackage ./pkgs/helix/default.nix { };
+
   hid = super.callPackage ./pkgs/hid/default.nix { };
   easyhid = super.callPackage ./pkgs/easyhid/default.nix { };
   openphone = super.callPackage ./pkgs/openphone/default.nix { };
diff --git a/pkgs/helix/default.nix b/pkgs/helix/default.nix
new file mode 100644
index 0000000..382104a
--- /dev/null
+++ b/pkgs/helix/default.nix
@@ -0,0 +1,40 @@
+{ fetchzip, lib, rustPlatform, git, installShellFiles }:
+
+rustPlatform.buildRustPackage rec {
+  pname = "helix";
+  version = "24.03";
+
+  # This release tarball includes source code for the tree-sitter grammars,
+  # which is not ordinarily part of the repository.
+  src = fetchzip {
+    url = "https://github.com/helix-editor/helix/releases/download/${version}/helix-${version}-source.tar.xz";
+    hash = "sha256-1myVGFBwdLguZDPo1jrth/q2i5rn5R2+BVKIkCCUalc=";
+    stripRoot = false;
+  };
+
+  cargoHash = "sha256-THzPUVcmboVJHu3rJ6rev3GrkNilZRMlitCx7M1+HBE=";
+
+  nativeBuildInputs = [ git installShellFiles ];
+
+  env.HELIX_DEFAULT_RUNTIME = "${placeholder "out"}/lib/runtime";
+
+  postInstall = ''
+    # not needed at runtime
+    rm -r runtime/grammars/sources
+
+    mkdir -p $out/lib
+    cp -r runtime $out/lib
+    installShellCompletion contrib/completion/hx.{bash,fish,zsh}
+    mkdir -p $out/share/{applications,icons/hicolor/256x256/apps}
+    cp contrib/Helix.desktop $out/share/applications
+    cp contrib/helix.png $out/share/icons/hicolor/256x256/apps
+  '';
+
+  meta = with lib; {
+    description = "A post-modern modal text editor";
+    homepage = "https://helix-editor.com";
+    license = licenses.mpl20;
+    mainProgram = "hx";
+    maintainers = with maintainers; [ danth yusdacra zowoq ];
+  };
+}