# Copyright 2021 Christian Ulrich
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# usage: ./part2 < input

import algorithm
import sequtils
import strutils

const Days = 256

proc predictLanternfishCount(): uint64 =
  let timers = readLine(stdin).split(',').mapIt(uint8(parseUint(it)))
  var counters: array[9, uint64]
  for timer in timers:
    if timer > 8:
      raise newException(ValueError, "invalid timer")
    counters[timer].inc()
  for day in 0 ..< Days:
    counters.rotateLeft(1)
    counters[6] += counters[8]
  result = counters.foldl(a + b, 0'u64)

proc main(): int =
  try:
    echo predictLanternfishCount()
  except Exception as error:
    echo error.msg
    result = -1

when isMainModule:
  quit(main())